Where does this program come from?

Here is the place to discuss about the magazines (CEO Mag, OUM, Rhetoric, Theoric, Hebdogiciel, ... are all welcome here) and books.
User avatar
Symoon
Archivist
Posts: 2337
Joined: Sat Jan 14, 2006 12:44 am
Location: Paris, France

Where does this program come from?

Post by Symoon »

I found this back on one of my own tapes, I seem to remember it was typed from a magazine but can't find which one. I thought it was from Micr'Oric (the French version of Oric Owner, well at least for a part of it), but I couldn't find it back in any of those magazines. So it might be from a book?
The reason I'm asking is that I found, on private tapes, lots of variations of this game, and I'd like to find back its original author.
Help! :wink:

Code: Select all

100 CLS
110 WA=60:BF=50:MU=100:CH=4:CA=50:EF=100:EC=100:MA=100
112 X=3.456:Y=4.345:AR=50
200 REM
210 CLS
215 J=J+1:PRINT"JOUR "J;:PRINT" - KILOMETRE " INT(KM)
216 IFKM=>1820 THENPRINT"VOUS ETES ARRIVES A BON PORT,BRAVO !":END
221 H=6:K=K+2:FR=K*1.5
222 PRINT"IL EST "H" HEURES":PRINT
225 FS=INT(RND(1)*100)+30
230 IFFS>100THENFS=100
235 PRINT"-ENSOLEILLEMENT...."FS;" %"
237 GOSUB1000
240 PRINT"-ETAT DU FOURGON..."EF;" %"
245 PRINT"-NOMBRE DE CHEVAUX."CH
247 PRINT"-ETAT DES CHEVAUX.."INT(EC);" %"
250 PRINT"-NOURRITURE........"BF" K"
260 PRINT"-EAU..............."WA" L"
262 PRINT"-MATERIEL.........."MA" %"
263 PRINT"-ARGENT............"AR" $"
265 PRINT:PRINT"LEVER LE CAMP ? (O/N)"
270 INPUT">";R$
275 IFR$="O"THEN350
280 PRINT"VOULEZ-VOUS:"
285 PRINT"-(R)EPARER LE CHARIOT ?"
290 PRINT"-(S)OIGNER LES CHEVAUX ?"
295 PRINT"-(M)ANGER/BOIRE ?"
300 PRINT"-(C)HASSER ?"
315 INPUT">";R$
320 IFR$="R"THENEF=EF+15:MA=MA-5:H=H+1
325 IFR$="S"THENWA=WA-6:EC=EC+18:H=H+1
330 IFR$="M"THENBF=BF-2:H=H+1
335 IFR$="M"THENM=0:WA=WA-4:BF=BF-1
340 IFR$="C"THENGOSUB900
342 IFTH=1THENTH=0:GOTO450
345 GOTO222
350 PRINT"COMBIEN DE CHEVAUX ATTELES ?";
355 INPUT">";NC
360 IFNC>CHORNC<1THEN350
370 PRINT"IL EST "H" HEURES":PRINT
400 PRINT:PRINT"YOHUUUUUUU!!"
405 FORI=1TO20:PRINT:NEXTI
410 FORT=HTO20STEP1
411 IFT<>14THEN450
415 PRINT"-(H)ALTE ? (O/N)";
420 INPUT">";R$
425 IFR$="O"THENTH=1:T=T+1:GOTO280
450 Z=(EF*EC*NC*X*Y)/(FS*4*MA)
452 IFZ<0THENZ=0
455 EF=EF-2
456 EC=EC-(FS*NC/150)
460 PRINTT" HEURES  "INT(Z)"KM"
462 KJ=KJ+Z
465 KM=KM+Z
470 NEXTT
472 PRINT"AUJOURD'HUI : "INT(KJ)" KM":KJ=0:EC=EC+5
475 PRINT"TOTAL PARCOURU : "INT(KM):M=M+2
480 INPUTA$
510 PR=INT(RND(1)*100)
520 IFPR>FRTHENGOTO800
521 PRINT"IL Y A UN FORT A "PR*J" METRES !"
530 PRINT"ALLEZ-VOUS AU FORT ? (O/N)"
535 INPUT">";R$
540 IFR$<>"O"THEN800
545 PRINT"VOUS ETES DANS LE FORT."
550 WA=60:M=0:FR=0:K=0:J=J+1:
555 IFAR=OTHEN700
560 PRINT"QUE VOULEZ-VOUS ACHETER ?"
565 PRINT"(C)ARTOUCHES...5 $"
570 PRINT"(CH)EVAL.......20$"
575 PRINT"(M)ATERIEL.....10$"
580 PRINT"(N)OURRITURE...2 $"
585 INPUT">";R$
590 IFR$="C"THENAR=AR-5:MU=MU+20
595 IFR$="CH"THENAR=AR-20:CH=CH+1
600 IFR$="M"THENAR=AR-10:MA=MA+20
605 IFR$="N"THENAR=AR-2:BF=BF+20
700 PRINT"VOULEZ-VOUS QUITTER LE FORT ? (O/N)"
710 INPUT">";R$
715 IFR$="O"THEN800
720 GOTO545
800 GOTO210
900 PC=INT(RND(1)*100)
905 T=T+1
910 IFPC<30ANDPC>20THENPRINT"UN VOL DE ANARD":G=1
915 IFPC<20ANDPC>10THENPRINT"UN LOUP":G=2
920 IFPC<10ANDPC>1THENPRINT"UN BISON":G=3
925 IFG=0THENPRINT"RIEN ! CONTINUEZ-VOUS L'AFFUT ?":GOTO930
926 RC=INT(RND(1)*100)
927 PRINT"PAN!!"
928 IFRC<50THENPRINT"REUSSI !":BF=INT(BF+(G*10)*(RC/10)):GOTO925
929 PRINT"RATE":G=0:GOTO925
930 INPUT">";R$
932 IFR$="O"THEN900
960 RETURN
1000 REM
1002 IFM>2THENPRINT"VOUS VOUS SENTEZ MAL" 
1005 IFM>10THENCLS:PRINT"BONJOUR LES VAUTOURS ! VOUS ETES MORT":END
1010 IFEF<0THENEF=0:PRINT"LE FOURGON NE ROULE PLUS"
1012 IFEF=0ANDMA=0THENPRINT"LES VAUTOURS TOURNENT DANS LE CIEL IMMACULE...":M=M+1
1020 IFCH<0THENCH=0
1030 IFBF<0THENBF=0:PRINT"PEUT-ETRE FAUDRAIT-IL CHASSER !":M=M+1
1040 IFWA<0THENWA=0:M=M+2:PRINT"SOIF...SOIF"
1050 IFMA<0THENMA=0:PRINT"HUMMM!!!"
1060 IFAR<0THENAR=0:PRINT"VOUS N'AVEZ PLUS D'ARGENT"
1065 IFAR=0ANDFR=1THENPRINT"VOUS TRAVAILLEZ PENDANT 2 SEMAINES...":J=J+15:AR=30
1070 IFEC<0THENEC=0
1100 RETURN
User avatar
Symoon
Archivist
Posts: 2337
Joined: Sat Jan 14, 2006 12:44 am
Location: Paris, France

Re: Where does this program come from?

Post by Symoon »

Found it back! :)
Thanks to LadyWasky in this post: https://oric.forumactif.org/t791-listin ... c-1-manual
This listing was adapted from Jeux Et Strategies magazine, issue 29: Kansas City, by Michel Brassinne.

The author actually based it on Oregon Trail program.
https://en.wikipedia.org/wiki/The_Orego ... ideo_game)
User avatar
ibisum
Wing Commander
Posts: 1675
Joined: Fri Apr 03, 2009 8:56 am
Location: Vienna, Austria
Contact:

Re: Where does this program come from?

Post by ibisum »

Neat! Here's an English translation (untested):

Code: Select all

100 CLS
110 WA=60:BF=50:MU=100:CH=4:CA=50:EF=100:EC=100:MA=100
112 X=3.456:Y=4.345:AR=50
200 REM
210 CLS
215 J=J+1:PRINT "DAY " J;:PRINT " - KILOMETER " INT(KM)
216 IF KM >= 1820 THEN PRINT "YOU HAVE ARRIVED AT YOUR DESTINATION, CONGRATULATIONS!":END
221 H=6:K=K+2:FR=K*1.5
222 PRINT "IT IS " H " O'CLOCK":PRINT
225 FS=INT(RND(1)*100)+30
230 IF FS > 100 THEN FS=100
235 PRINT "-SUNLIGHT........" FS; " %"
237 GOSUB 1000
240 PRINT "-WAGON CONDITION.." EF; " %"
245 PRINT "-NUMBER OF HORSES." CH
247 PRINT "-CONDITION OF HORSES.." INT(EC); " %"
250 PRINT "-FOOD............" BF " K"
260 PRINT "-WATER..........." WA " L"
262 PRINT "-EQUIPMENT......." MA " %"
263 PRINT "-MONEY..........." AR " $"
265 PRINT:PRINT "BREAK CAMP? (Y/N)"
270 INPUT ">"; R$
275 IF R$="Y" THEN 350
280 PRINT "DO YOU WANT TO:"
285 PRINT "-(R)EPAIR THE WAGON?"
290 PRINT "-(T)REAT THE HORSES?"
295 PRINT "-(E)AT/DRINK?"
300 PRINT "-(H)UNT?"
315 INPUT ">"; R$
320 IF R$="R" THEN EF=EF+15:MA=MA-5:H=H+1
325 IF R$="T" THEN WA=WA-6:EC=EC+18:H=H+1
330 IF R$="E" THEN BF=BF-2:H=H+1
335 IF R$="E" THEN M=0:WA=WA-4:BF=BF-1
340 IF R$="H" THEN GOSUB 900
342 IF TH=1 THEN TH=0:GOTO 450
345 GOTO 222
350 PRINT "HOW MANY HORSES ARE HARNESSED?";
355 INPUT ">"; NC
360 IF NC>CH OR NC<1 THEN 350
370 PRINT "IT IS " H " O'CLOCK":PRINT
400 PRINT:PRINT "YOHUUUUUUU!!"
405 FOR I=1 TO 20:PRINT:NEXT I
410 FOR T=H TO 20 STEP 1
411 IF T<>14 THEN 450
415 PRINT "-(S)TOP? (Y/N)";
420 INPUT ">"; R$
425 IF R$="Y" THEN TH=1:T=T+1:GOTO 280
450 Z=(EF*EC*NC*X*Y)/(FS*4*MA)
452 IF Z<0 THEN Z=0
455 EF=EF-2
456 EC=EC-(FS*NC/150)
460 PRINT T " HOURS  " INT(Z) "KM"
462 KJ=KJ+Z
465 KM=KM+Z
470 NEXT T
472 PRINT "TODAY: " INT(KJ) " KM":KJ=0:EC=EC+5
475 PRINT "TOTAL DISTANCE COVERED: " INT(KM):M=M+2
480 INPUT A$
510 PR=INT(RND(1)*100)
520 IF PR>FR THEN GOTO 800
521 PRINT "THERE IS A FORT AT " PR*J " METERS!"
530 PRINT "WILL YOU GO TO THE FORT? (Y/N)"
535 INPUT ">"; R$
540 IF R$<>"Y" THEN 800
545 PRINT "YOU ARE IN THE FORT."
550 WA=60:M=0:FR=0:K=0:J=J+1:
555 IF AR=0 THEN 700
560 PRINT "WHAT DO YOU WANT TO BUY?"
565 PRINT "(C)ARTRIDGES...5 $"
570 PRINT "(H)ORSE.......20$"
575 PRINT "(E)QUIPMENT.....10$"
580 PRINT "(F)OOD...2 $"
585 INPUT ">"; R$
590 IF R$="C" THEN AR=AR-5:MU=MU+20
595 IF R$="H" THEN AR=AR-20:CH=CH+1
600 IF R$="E" THEN AR=AR-10:MA=MA+20
605 IF R$="F" THEN AR=AR-2:BF=BF+20
700 PRINT "DO YOU WANT TO LEAVE THE FORT? (Y/N)"
710 INPUT ">"; R$
715 IF R$="Y" THEN 800
720 GOTO 545
800 GOTO 210
900 PC=INT(RND(1)*100)
905 T=T+1
910 IF PC<30 AND PC>20 THEN PRINT "A DUCK RAID":G=1
915 IF PC<20 AND PC>10 THEN PRINT "A WOLF":G=2
920 IF PC<10 AND PC>1 THEN PRINT "A BISON":G=3
925 IF G=0 THEN PRINT "NOTHING! DO YOU CONTINUE TO WATCH?":GOTO 930
926 RC=INT(RND(1)*100)
927 PRINT "BANG!!"
928 IF RC<50 THEN PRINT "SUCCESS!":BF=INT(BF+(G*10)*(RC/10)):GOTO 925
929 PRINT "MISSED":G=0:GOTO 925
930 INPUT ">"; R$
932 IF R$="Y" THEN 900
960 RETURN
1000 REM
1002 IF M>2 THEN PRINT "YOU FEEL SICK" 
1005 IF M>10 THEN CLS:PRINT "HELLO VULTURES! YOU ARE DEAD":END
1010 IF EF<0 THEN EF=0:PRINT "THE WAGON DOESN'T MOVE ANYMORE"
1012 IF EF=0 AND MA=0 THEN PRINT "THE VULTURES ARE CIRCLING IN THE CLEAR SKY...":M=M+1
1020 IF CH<0 THEN CH=0
1030 IF BF<0 THEN BF=0:PRINT "MAYBE YOU SHOULD HUNT!":M=M+1
1040 IF WA<0 THEN WA=0:M=M+2:PRINT "THIRST...THIRST"
1050 IF MA<0 THEN MA=0:PRINT "HMMM!!!"
1060 IF AR<0 THEN AR=0:PRINT "YOU HAVE NO MORE MONEY"
1065 IF AR=0 AND FR=1 THEN PRINT "YOU WORK FOR 2 WEEKS...":J=J+15:AR=30
1070 IF EC<0 THEN EC=0
1100 RETURN
User avatar
Symoon
Archivist
Posts: 2337
Joined: Sat Jan 14, 2006 12:44 am
Location: Paris, France

Re: Where does this program come from?

Post by Symoon »

Ha ha thanks!
Now we got:
- the Jeux Et Stratégies version adapted to Oric by my brother (well, he put CLS instead of HOME ;) )
- Ibisum's English translation
- a Club Europe Oric version, visually enhanced, but unplayable since it doesn't display the wagon state
- a Frederic Wolinksi 1.1 version for Telestrat

Mmmmh, got to figure how to sort this on Oric.org
Post Reply