Non running game

Want to talks about games you like, would like to see developed on the Oric, it's here.
coolman66
Flying Officer
Posts: 244
Joined: Wed Jul 14, 2010 7:37 pm
Location: lancashire GB
Contact:

Non running game

Post by coolman66 »

Trayed to load the game car war the from Hebdo in Oric.org when cloaded it looks for a second part it seems but I downloaded from Oric.org so don’t know what’s going on , any ideas ?
User avatar
Dbug
Site Admin
Posts: 4444
Joined: Fri Jan 06, 2006 10:00 pm
Location: Oslo, Norway
Contact:

Re: Non running game

Post by Dbug »

The only "Car War" I can see on oric.org is the one in Théoric.
https://www.oric.org/software/car_war__the-1795.html

If you don't provide any details, links, etc... I doubt people can help.
coolman66
Flying Officer
Posts: 244
Joined: Wed Jul 14, 2010 7:37 pm
Location: lancashire GB
Contact:

Re: Non running game

Post by coolman66 »

I am sorry ive not made myself clear ,that is the one that doesnt work on my laptop ! I will put a copy on here for other people to try and maybe come up with an answer why i cant get it to run , sorry about the confusion !
CARWAR.tap
(10.78 KiB) Downloaded 134 times
coolman66
Flying Officer
Posts: 244
Joined: Wed Jul 14, 2010 7:37 pm
Location: lancashire GB
Contact:

Re: Non running game

Post by coolman66 »

In the meantime there is another little game with a similar name but by a guy called Christophe Andeani its quite nice !
car war oric 1.tap
(6.7 KiB) Downloaded 139 times
User avatar
iss
Wing Commander
Posts: 1641
Joined: Sat Apr 03, 2010 5:43 pm
Location: Bulgaria
Contact:

Re: Non running game

Post by iss »

coolman66 wrote: Wed May 04, 2022 2:56 pm... CARWAR.tap ...
About 'CARWAR.tap': The one you attached above and the one on oric.org are THE SAME - 11038 bytes!
The game doesn't work because in the TAP file is only one part in BASIC (loaded in #501 ... #3005):

Code: Select all

1 HIMEM#8000:TEXT
2 DOKE#306,10000
5 CLOAD"CARCODE"
135 DOKE#930D,#9610
990 IF PEEK(#9600)=32 THEN 1330
1000 REM
1010 REM   IMPLANTATION DE LA ROUTINE
1020 REM          MULTITOUCHE
1030 REM
1035 S=0:M=0
1040 LG=1100:FOR L=10 TO 9 STEP -1:K=0:FOR I=0 TO L:FOR J=1 TO 6
1050 READ DT:POKE#9600+K+M,DT:S=S+DT:K=K+1:NEXT:READ SC
1060 IF S<>SC THEN PRINT"ERREUR !!! LIGNE ";LG;" A VERIFIER."
1070 LG=LG+10:S=0:NEXT
1090 IF L=10 THEN M=#50:NEXT
1100 DATA #20,#22,#D9,#A5,#34,#D0,708
1110 DATA #06,#C0,#3A,#B0,#02,#90,578
1120 DATA #03,#4C,#36,#D3,#B9,#50,609
1130 DATA #96,#48,#29,#07,#A8,#68,542
1140 DATA #4A,#4A,#4A,#AA,#A9,#FE,815
1150 DATA #38,#D0,#01,#2A,#CA,#10,525
1160 DATA #FC,#AA,#98,#48,#A9,#0E,829
1170 DATA #20,#90,#F5,#68,#09,#B8,718
1180 DATA #8D,#00,#03,#A0,#00,#AD,477
1190 DATA #00,#03,#29,#08,#F0,#02,294
1200 DATA #A0,#01,#4C,#B6,#D4,#00,631
1210 DATA #28,#32,#38,#1A,#10,#0A,198
1220 DATA #00,#07,#0B,#17,#1B,#3F,131
1230 DATA #33,#29,#31,#3E,#1E,#11,250
1240 DATA #09,#06,#05,#0D,#15,#1D,83
1250 DATA #3D,#35,#2D,#22,#2E,#36,293
1260 DATA #39,#19,#16,#0E,#01,#03,122
1270 DATA #0F,#13,#3B,#2F,#24,#2A,218
1280 DATA #30,#3A,#18,#12,#08,#02,158
1290 DATA #0C,#14,#1F,#27,#2C,#34,198
1300 DATA #04,#1C,#3C,#25,#00,#00,129
1310 IF PEEK(#FFF9)<>196 THEN 1330
1320 DOKE#9601,#D867:DOKE#960E,#D2A0:DOKE#962B,#F535:DOKE#963F,#D3FD
1330 POKE#963E,96:DOKE#9090,#9610:DOKE#90E2,#9610:DOKE#92BB,#9610
1340 CLS
1350 GOSUB 60000
1390 GOTO 1790
1400 REM
1410 REM REDEFINITIONS DES CARACTERES
1420 REM
1425 DOKE #B0,2+DEEK(#E9):RETURN
1430 DATA 0,0,31,16,23,20,20,20
1440 DATA 0,0,62,2,58,10,10,10
1450 DATA 20,20,20,23,16,31,0,0
1460 DATA 10,10,10,58,2,62,0,0
1470 DATA 20,20,20,20,20,20,20,20
1480 DATA 10,10,10,10,10,10,10,10
1490 DATA 0,0,63,0,63,0,0,0
1500 DATA 0,0,0,63,0,63,0,0
1510 DATA 12,30,12,12,12,63,63,12
1520 DATA 12,63,63,12,12,12,30,12
1530 DATA 0,24,26,63,63,26,24,0
1540 DATA 0,6,22,63,63,22,6,0
1550 DATA 0,0,32,16,8,36,20,20
1560 DATA 18,09,4,2,1,0,0,0
1570 DATA 18,36,8,16,32,0,0,0
1580 DATA 0,0,1,2,4,9,10,10
1590 DATA 28,20,20,20,20,20,20,20
1600 DATA 20,20,20,20,20,20,20,28
1610 DATA 14,10,10,10,10,10,10,10
1620 DATA 10,10,10,10,10,10,10,14
1630 DATA 0,0,63,1,63,0,0,0
1640 DATA 0,0,63,62,63,0,0,0
1650 DATA 0,0,0,63,1,63,0,0
1660 DATA 0,0,0,63,32,63,0,0
1790 GOSUB 1425
1800 FOR I=39688 TO 39879
1810 READ D:POKEI,D
1820 NEXT
1830 A=46424:DOKEA,0:POKEA+2,8:POKEA+3,28:POKEA+4,8:DOKEA+5,0:POKEA+7,0
2000 REM
2010 REM    COMPATIBILITE O1/AT
2020 REM
2030 IF PEEK(#FFF9)<>1 THEN DD=-1
3000 GOTO 3100
3010 M$=C$+M$
3020 FOR I=38 TO 2 STEP -1
3025 PLOT I-1+DD,Y,"l"
3030 PLOT I+DD,Y,LEFT$(M$,39-I)
3040 M$=M$+" "
3050 NEXT
3055 PLOT 1+DD,Y," "
3056 Y=Y+1
3060 RETURN
3070 M$="      PRESSEZ LA TOUCHE W":Y=23:GOSUB3010:GETR$:IFR$="W"THENRETURN
3080 M$="ON VOUS A DIT W ET VOUS TAPEZ ":Y=25:GOSUB 3010
3085 M$="AILLEURS.   CA COMMENCE BIEN !!!":GOSUB 3010:WAIT 300:RETURN
3100 TEXT:PAPER0:INK7:CLS:POKE618,10
3105 C$=CHR$(2)
3110 M$="           THE CAR WAR":Y=2:GOSUB 3010
3120 M$="           ===========":Y=3:GOSUB 3010
3130 M$="         AUTEUR: ERIC VIEL":Y=5:GOSUB3010
3140 C$=CHR$(4):Y=8
3150 M$="   LES MOTEURS TOURNAIENT, LE BRUIT EN":GOSUB 3010
3160 M$="ETAIT ASSOURDISSANT. UN DERNIER COUP"
3165 GOSUB 3010
3170 M$="D'OEIL SUR LE FEU."
3175 GOSUB 3010
3180 M$="VERT."
3185 GOSUB 3010
3190 M$="D'UN SEUL COUP, LE BOLIDE PARTIT EN   "
3195 GOSUB 3010
3200 M$="AVANT. IL FALLAIT ARRIVER AU CROISE-"
3205 GOSUB 3010
3210 M$="MENT AVANT L'AUTRE..."
3215 GOSUB 3010
3220 M$="L'AUTRE, C'EST VOUS. ET VOUS DEVEZ"
3225 GOSUB 3010
3230 M$="FAIRE DE MEME. POUR GAGNER CETTE"
3235 GOSUB 3010
3240 M$="LUTTE, VOICI QUELQUES CONSEILS ..."
3245 GOSUB 3010
3250 GOSUB 3070
3260 CLS:Y=1:M$="         THE CAR WAR":GOSUB3010:C$=CHR$(5):Y=5
3270 M$="LE BUT DU JEU EST DE FAIRE LE "
3275 GOSUB 3010
3280 M$="MAXIMUM DE POINTS. (ETONANT, NON ?)"
3285 GOSUB 3010
3290 M$="POUR CELA CHAQUE JOUEUR POSSEDE 3"
3295 GOSUB 3010
3300 M$="VOITURES. LE JOUEUR 1 DEMARRE A"
3305 GOSUB 3010
3310 M$="GAUCHE ET LE JOUEUR 2 DEMARRE A"
3315 GOSUB 3010
3320 M$="DROITE. LE JOUEUR 1 CONTROLE SON "
3325 GOSUB 3010
3330 M$="VEHICULE A L'AIDE DES TOUCHES "
3335 GOSUB 3010
3340 M$="FLECHE GAUCHE POUR ALLER VERS"
3345 GOSUB 3010
3350 M$="L'INTERIEUR ET FLECHE BAS POUR ALLER"
3355 GOSUB 3010
3360 M$="VERS L'EXTERIEUR."
3365 GOSUB 3010
3370 M$="LE JOUEUR 2 DISPOSE DE LA FLECHE "
3375 GOSUB 3010
3380 M$="HAUT POUR ALLER A L'EXTERIEUR ET"
3385 GOSUB 3010
3390 M$="DE LA FLECHE DROITE POUR ALLER A"
3395 GOSUB 3010
3400 M$="L'INTERIEUR DU CIRCUIT."
3405 GOSUB 3010
3410 GOSUB 3070
3420 CLS:Y=1:M$="          THE CAR WAR":GOSUB 3010
3430 C$=CHR$(2)
3440 Y=6
3450 M$="LORSQUE LES DEUX JOUEURS SE"
3455 GOSUB 3010
3460 M$="RENCONTRENT, ILS NE PEUVENT PAS SE"
3465 GOSUB 3010
3470 M$="RACONTER DES HISTOIRES DE JOUEURS,"
3475 GOSUB 3010
3480 M$="VU QU'ILS VIENNENT DE SE TUER !!!"
3485 GOSUB 3010
3490 M$="ILS N'ONT PAS SEPT VIES COMME LES"
3495 GOSUB 3010
3500 M$="CHATS, MAIS TROIS. ALORS, GAFFE !!!"
3505 GOSUB 3010
3510 M$=" "
3515 GOSUB 3010
3520 M$="REMARQUES, TOUS LES TROIS TABLEAUX"
3525 GOSUB 3010
3530 M$="ILS GAGNENT UNE VOITURE, MAXIMUM "
3535 GOSUB 3010
3540 M$="TROIS VOITURES SIMULTANEMENT, ALORS"
3545 GOSUB 3010
3550 M$="ILS PEUVENT PEUT ETRE EN AVOIR SEPT"
3555 GOSUB 3010
3560 M$="ENCORE QUE L'AUTEUR AIT PENSE A"
3565 GOSUB 3010
3570 M$="AUGMENTER LA DIFFICULTE A CHAQUE"
3575 GOSUB 3010
3580 M$="TABLEAU, ALORS, ..."
3585 GOSUB 3010
3590 M$=" "
3595 GOSUB 3010
3600 M$="        ALORS, A VOUS DE JOUER !!!"
3605 GOSUB 3010
3610 GOSUB 3070
5000 REM
8990 MS=500
9000 REM
9010 REM   INITIALISATIONS
9020 REM
9040 E$=CHR$(27)
9050 D$=CHR$(4)
9100 NC=3
9110 S1$="00000":S2$=S1$
9120 POKE#94A8,80
10000 REM
10010 REM DESSIN DU TERRAIN
10020 REM
10025 PAPER 4:INK6
10030 CLS:POKE 618,10
11000 PRINT
11010 PRINT"agggggm    pgggmpggggggggggb"
11020 PRINT"e+++++nggggo+++no++++++++++f"
11030 PRINT"e++++++++++++++++++++++++++f"
11040 PRINT"e+aggggggggggggggu++++vggb+f"
11050 PRINT"e+e++++++++++++++++++++++f+f"
11060 PRINT"e+e+aggggggu++++vggggggb+f+f"
11070 PRINT"e+e+e++++++++++++++++++f+f+f"
11080 PRINT"e+e+e+aggggu++++vggggb+f+f+f"
11090 PRINT"e+e+e+e++++++++++++++f+f+f+f"
11100 PRINT"e+r+r+e+aggggggggggb+f+t+t+f"
11110 PRINT"e+++++r+e          f+t+++++f"
11111 PRINT"e+++++++e          f+++++++f"
11130 PRINT"e+++++++e          f+++++++f"
11140 PRINT"e+++++q+e          f+s+++++f"
11160 PRINT"e+q+q+e+chhhhhhhhhhd+f+s+s+f"
11170 PRINT"e+e+e+e++++++++++++++f+f+f+f"
11180 PRINT"e+e+e+chhhhw++++xhhhhd+f+f+f"
11190 PRINT"e+e+e++++++++++++++++++f+f+f"
11200 PRINT"e+e+chhhhhhw++++xhhhhhhd+f+f"
11210 PRINT"e+e++++++++++++++++++++++f+f"
11220 PRINT"e+chhhhhhhhw++++xhhhhhhhhd+f"
11230 PRINT"e++++++++++++++++++++++++++f"
11240 PRINT"chhhhhhhhhhhhhhhhhhhhhhhhhhd"
11250 PRINT "e r r r f          e t t t f"
11260 PRINT "e       f          e       f"
11270 PRINT "chhhhhhhd          chhhhhhhd";CHR$(30)
12000 PLOT 31+DD,16,"JOUEUR 1"
12010 PLOT 31+DD,21,"JOUEUR 2"
12020 PLOT 31+DD,18,S1$
12030 PLOT 31+DD,23,S2$
12040 PLOT 31+DD,11,"HI-SCORE"
12050 PLOT 31+DD,13,MID$(STR$(MS),2)
12060 PLOT 31+DD,3,"THE"
12070 PLOT 31+DD,5,"  CAR"
12080 PLOT 31+DD,7,"    WAR"
12090 PLOT 31+DD,9,"========="
12095 GOTO 12500
12100 REM
12110 REM    SORTIE DU GARAGE
12120 REM
12125 TP=65
12130 P1=3+NC*2:P2=28-NC*2
12140 PLOT P1+DD,24," ":PLOT P2+DD,24," "
12150 PLOT P1+DD,25,"j":PLOT P2+DD,25,"j"
12155 WAIT TP
12160 PLOT P1+DD,25,"l":PLOT P2+DD,25,"k"
12165 WAIT TP
12170 FOR I=1 TO NC*2
12180 PLOT P1+DD,25," ":PLOT P2+DD,25," "
12190 P1=P1-1:P2=P2+1
12200 PLOT P1+DD,25,"l":PLOT P2+DD,25,"k"
12210 WAIT TP:NEXT
12220 PLOT P1+DD,25,"i":PLOT P2+DD,25,"i":WAIT TP
12230 PLOT P1+DD,25," ":PLOT P2+DD,25," "
12240 PLOT P1+DD,24,"i":PLOT P2+DD,24,"i":WAIT TP
12250 PLOT P1+DD,23," ":PLOT P2+DD,23," ":WAIT TP
12260 PLOT P1+DD,24," ":PLOT P2+DD,24," "
12270 PLOT P1+DD,23,"i":PLOT P2+DD,23,"i":WAIT TP
12280 PLOT P1+DD,23," ":PLOT P2+DD,23," "
12290 PLOT P1+DD,22,"i":PLOT P2+DD,22,"i":WAIT TP
12300 PLOT P1+DD,23,"h":PLOT P2+DD,23,"h":WAIT TP
12310 PLOT P1+DD,22,"k":PLOT P2+DD,22,"l":WAIT TP
12490 RETURN
12500 PLOT 13+DD,25,"GARAGE"
12510 P1=5:P2=26:FOR I=1 TO NC
12520 PLOT P1+DD,24,"j":PLOT P2+DD,24,"j":P1=P1+2:P2=P2-2:NEXT
13315 PRINT
15000 REM
15010 REM   JEU
15020 REM
15030 GOSUB 12100
15035 PLOT 12+DD,11,"        "
15037 PLOT 12+DD,13,"       "
15040 PLOT 12+DD,11,"PRETS ?"
15050 PLOT 14+DD,13,17:PLOT15+DD,13,20
15060 PLAY 1,0,0,0:MUSIC 1,2,2,10:WAIT 40:PLAY 0,0,0,0
15065 WAIT 0100
15070 PLOT 12+DD,11,"PARTEZ!"
15080 PLOT 14+DD,13,18:PLOT15+DD,13,20
15090 MUSIC 1,2,11,10:PLAY 1,0,0,0:WAIT 40:PLAY 0,0,0,0
15100 PLOT 12+DD,11,"(C) ERIC"
15110 PLOT 12+DD,13,"  VIEL "
15120 DOKE#8F20,599:CALL#9038
15121 S1$="":S2$="":FOR I=31 TO 35:S1$=S1$+CHR$(SCRN(I+DD,18))
15122 S2$=S2$+CHR$(SCRN(I+DD,23)):NEXT
15130 IF PEEK(#BFE1)=2 THEN 16000
15140 EXPLODE:WAIT 32:EXPLODE
15150 POKE DEEK(02),32:POKE DEEK(06),32
15160 POKE DEEK(00),32:POKE DEEK(04),32
15170 NC=NC-1:IF NC>0 THEN 15000
15180 CLS:PAPER4
15185 PRINT:A$=KEY$:A$=KEY$
15190 PRINT"  "D$E$"J"E$"C   CHAUFFARDS !!!"
15200 PRINTD$
15210 PRINT:PRINT:PRINT"  VOUS VENEZ DE BOUSILLER A VOUS DEUX"
15220 PRINT"UN BON NOMBRE DE VEHICULES DE F1."
15230 PRINT"HEUREUSEMENT POUR VOUS, ILS ETAIENT"
15240 PRINT"EQUIPES DE MOTEURS FRANCAIS. LE "
15250 PRINT"PRESIDENT DE LA REPUBLIQUE VOUS FAIT"
15260 PRINT"GRACE DE LA FACTURE (CELA FAIT MARCHER";
15270 PRINT"L'INDUSTRIE, C'EST BON ...)"
15280 PRINT:PRINT"   VOUS GARDEZ DONC LE BENEFICE DE "
15290 PRINT"VOS POINTS, A SAVOIR ..."
15300 PRINT:PRINT"   JOUEUR 1 .......... "S1$
15310 PRINT"   JOUEUR 2 .......... "S2$
15320 IF S1$>S2$ THEN SC=VAL(S1$):M$="1" ELSE SC=VAL(S2$):M$="2"
15330 IF SC<MS THEN 15380
15340 PRINT:PRINT:PRINT"VU LE HAUT SCORE DU JOUEUR "M$","
15350 PRINT"LE PRESIDENT LUI REMETTRA LA CROIX DU"
15360 PRINT"BRIZ' FAIR .":MS=SC
15370 GOTO 15430
15380 PRINT"DE PLUS, VOUS N'AVEZ PAS BATTU LE "
15390 PRINT"RECORD.  LE PRESIDENT NE VOUS FAIT"
15400 PRINT"PAS DE COMPLIMENTS. (NOTE DU"
15410 PRINT"PROGRAMMEUR : C'EST PAS COMME CA QU'IL";
15420 PRINT"VA SE FAIRE REELIRE ...)"
15430 PLOT DD+10,25,"PRESSEZ UNE TOUCHE":GETR$
15450 GOTO 9000
16000 REM
16010 REM   TABLEAU PASSE
16020 REM
16025 TB=TB+1
16030 FOR I=1 TO 53:PRINT:NEXT
16040 PRINT"         "E$"L FELICITATIONS"
16050 PRINT:PRINT:PRINT:PRINT:PRINT:PRINT"NOMBRE DE TABLEAUX PASSES: "TB
16060 PRINT:PRINT:PRINT:PRINT:PRINT"          "E$"L  SCORES"
16070 PRINT:PRINT:PRINT:PRINT:PRINT"JOUEUR 1 ......... "S1$
16080 PRINT:PRINT"JOUEUR 2 ......... "S2$
16090 PRINT:PRINT:PRINT:PRINT"PETITE PAUSE ...."
16100 WAIT 150
16110 PLOT 2+DD,25,"                   "
16120 IF NC = 3 THEN 16200
16130 IF INT (TB/3)<>TB/3 THEN 16200
16140 PRINT:PRINT:PRINT:PRINT:PRINT
16145 NC=NC+1
16160 WAIT 100
16200 REM
16210 A=PEEK(#94A8):A=A-5:IF A<10 THEN A=10
16220 POKE #94A8,A
16230 GOTO 10000
60000 PAPER 1:INK3
60010 HIRES:POKE618,10
60020 CURSET 20,50,3
60030 N=4:FOR J=1 TO 6
60040 FOR I=1 TO N
60050 CHAR 127,0,1:CURMOV 12,0,3:NEXT
60060 N=N+0.5
60070 CURSET 20-6*(INT(J/2)=J/2),50+(J-1)*8,3:NEXT
60080 CURSET 74,58,3:CHAR 127,0,0
60090 CURSET 86,74,3:CHAR 127,0,0
60100 FOR I=1 TO 6
60110 CURSET 56+I,50,1:DRAW 66,88,1
60120 NEXT
60130 CURSET 220,50,3
60140 N=4:FOR J=1 TO 6
60150 FOR I=1 TO N
60160 CHAR 127,0,1:CURMOV -12,0,3:NEXT
60170 N=N+0.5
60180 CURSET 240-(20-6*(INT(J/2)=J/2)),50+(J-1)*8,3:NEXT
60190 CURSET 166,58,3:CHAR 127,0,0
60200 CURSET 154,74,3:CHAR 127,0,0
60210 FOR I=6 TO 1 STEP-1
60220 CURSET 183+I,50,1:DRAW -66,88,1
60230 NEXT
60240 :
60250 :
60260 CURSET 93,50,3:M$="ERIC  VIEL":GOSUB 60720
60270 CURSET 93,62,3:M$=" PRESENTE ":GOSUB 60720
60280 CURSET 10,150,1:DRAW 16,0,1
60290 CURSET 18,150,1:DRAW 0,20,1
60300 CURSET 30,150,1:DRAW 0,20,1
60310 CURSET 46,150,1:DRAW 0,20,1
60320 CURSET 46,160,1:DRAW -16,0,1
60330 CURSET 66,150,1:DRAW -16,0,1:DRAW 0,20,1:DRAW 16,0,1
60340 CURSET 50,160,1:DRAW 8,0,1
60350 CURSET 102,150,1:DRAW -16,0,1:DRAW 0,20,1:DRAW 16,0,1
60360 CURSET 106,170,1:DRAW 0,-20,1:DRAW 16,0,1:DRAW 0,20,1
60370 CURSET 106,160,1:DRAW 16,0,1
60380 CURSET 126,170,1:DRAW 0,-20,1:DRAW 16,0,1:DRAW 0,10,1:DRAW -16,0,1
60390 DRAW 6,0,1:DRAW 10,10,1
60400 CURSET 166,150,1:DRAW 0,20,1:DRAW 10,-7,1:DRAW 10,7,1:DRAW 0,-20,1
60410 CURSET 190,170,1:DRAW 0,-20,1:DRAW 16,0,1:DRAW 0,20,1
60420 CURSET 190,160,1:DRAW 16,0,1
60430 CURSET 210,170,1:DRAW 0,-20,1:DRAW 16,0,1:DRAW 0,10,1:DRAW -16,0,1
60440 DRAW 6,0,1:DRAW 10,10,1
60450 :
60460 GOTO 60545
60465 DOKE#B0,2+DEEK(#E9):RETURN
60470 DATA #A2,#C3,#A0,#28,#B9,#28,#A0
60480 DATA #99,#00,#A0,#88,#D0,#F7
60490 DATA #18,#AD,#05,#80,#69,#28,#8D,#05,#80
60500 DATA #AD,#06,#80,#69,#00,#8D,#06,#80
60510 DATA #18,#AD,#08,#80,#69,#28,#8D,#08,#80
60520 DATA #AD,#09,#80,#69,#00,#8D,#09,#80
60530 DATA #CA,#F0,#03,#4C,#02,#80,#60
60540 DATA 999
60545 GOSUB 60465
60550 A=#8000:READ D
60560 REPEAT:POKE A,D:A=A+1:READD
60570 UNTIL D=999
60580 FOR I=1 TO 140:DOKE #8005,#A028:DOKE#8008,#A000:CALL#8000:NEXT
60590 CURSET 50,150,3:CIRCLE 10,1
60600 CURSET 170,145,3:CIRCLE 15,1
60610 CURSET 200,143,1:DRAW -14,2,1
60620 CURSET 154,145,1:DRAW -93,5,1
60630 CURSET 40,150,1:DRAW -20,2,1
60640 DRAW 40,-20,1:DRAW 140,-15,1
60650 DRAW 0,15,1:DRAW 5,0,1:DRAW 0,3,1:DRAW-5,0,1:DRAW 0,7,1
60660 CURSET 103,127,1:DRAW 7,-5,1:DRAW 22,-6,1:DRAW 2,8,1
60670 CURSET 180,119,1:DRAW 0,-10,1:DRAW -20,2,1:DRAW 0,9,1:DRAW 0,-9,1
60680 DRAW -15,2,1:DRAW 3,-5,1:DRAW 50,-5,1:DRAW -3,+5,1
60690 DRAW -15,1,1
60700 CURSET 097,130,3:M$="Eric Viel"
60710 GOSUB60720:PRINT:PRINT"VEUILLEZ PATIENTER QUELQUES INSTANTS..":RETURN
60720 FOR C=1 TO LEN(M$):CHARASC(MID$(M$,C,1)),0,1:CURMOV 6,0,3:NEXT:RETURN
Looking at line #5:

Code: Select all

5 CLOAD"CARCODE"
There should be a second part in the TAP file which obviously is missing. That's all!
It would be interesting if someone has the original to post it ... ;).
Jonh
Pilot Officer
Posts: 71
Joined: Tue Jun 01, 2021 4:07 pm
Location: Cambridge, UK

Re: Non running game

Post by Jonh »

Here you go - the curious repeat of the loading screen is true to the original Theoric listing...
THECARWAR.TAP
(14.18 KiB) Downloaded 132 times
I have updated Oric.org
coolman66
Flying Officer
Posts: 244
Joined: Wed Jul 14, 2010 7:37 pm
Location: lancashire GB
Contact:

Re: Non running game

Post by coolman66 »

Thanks Jonh this throws up a puzzle for me becourse the working one i had came up with a title screen saying ORIC1PRESENTS and then says the author is called Cristophe Andreani ?
User avatar
Symoon
Archivist
Posts: 2307
Joined: Sat Jan 14, 2006 12:44 am
Location: Paris, France

Re: Non running game

Post by Symoon »

Car War by Christophe Andréani was published in Micr'Oric 6 (automn 1984), and The Car War by Eric Viel was published in Théoric 29 (March 1987). Both French magazines.
Jonh
Pilot Officer
Posts: 71
Joined: Tue Jun 01, 2021 4:07 pm
Location: Cambridge, UK

Re: Non running game

Post by Jonh »

Yes, the first (CarWar-Oric1) is single-player, written in 7k of Basic. The second is 15k of Basic and M/C, two-player, Oric-1 and Atmos compatible, and much more sophisticated. But inspired by the first version, no doubt!
User avatar
iss
Wing Commander
Posts: 1641
Joined: Sat Apr 03, 2010 5:43 pm
Location: Bulgaria
Contact:

Re: Non running game

Post by iss »

Hm, Car War .... I prefer Car Wash :lol:
car-wash.png
Attachments
car-wash.tap
(7.89 KiB) Downloaded 123 times
Post Reply